#!/usr/bin/perl -w
# NAME: shwgiturls.pl
# AIM: Given a directory input, search for git repos in the subdirectories, and 
#      show the REPO and DATE
use strict;
use warnings;
use File::Basename;  # split path ($name,$dir,$ext) = fileparse($file [, qr/\.[^.]*/] )
use File::stat;
use Time::gmtime;
use Cwd;
my $os = $^O;
my $perl_dir = '/home/geoff/bin';
my $PATH_SEP = '/';
my $temp_dir = '/tmp';
if ($os =~ /win/i) {
    $perl_dir = 'C:\GTools\perl';
    $temp_dir = $perl_dir;
    $PATH_SEP = "\\";
}
unshift(@INC, $perl_dir);
require 'lib_utils.pl' or die "Unable to load 'lib_utils.pl' Check paths in \@INC...\n";
# log file stuff
our ($LF);
my $pgmname = $0;
if ($pgmname =~ /(\\|\/)/) {
    my @tmpsp = split(/(\\|\/)/,$pgmname);
    $pgmname = $tmpsp[-1];
}
my $outfile = $temp_dir.$PATH_SEP."temp.$pgmname.txt";
open_log($outfile);

# user variables
my $VERS = "0.0.5 2015-01-09";
my $load_log = 0;
my $in_dir = '';
my $verbosity = 0;
my $out_file = '';

# ### DEBUG ###
my $debug_on = 0;
my $def_file = 'F:\FGx';

### program variables
my @warnings = ();
my $cwd = cwd();
my @gitrepos = ();
my $total_dirs = 0;
my $total_files = 0;
my $max_path = 0;
my $max_repo = 0;

my %repos_found = ();

sub VERB1() { return $verbosity >= 1; }
sub VERB2() { return $verbosity >= 2; }
sub VERB5() { return $verbosity >= 5; }
sub VERB9() { return $verbosity >= 9; }

sub show_warnings($) {
    my ($val) = @_;
    if (@warnings) {
        prt( "\nGot ".scalar @warnings." WARNINGS...\n" );
        foreach my $itm (@warnings) {
           prt("$itm\n");
        }
        prt("\n");
    } else {
        prt( "\nNo warnings issued.\n\n" ) if (VERB9());
    }
}

sub pgm_exit($$) {
    my ($val,$msg) = @_;
    if (length($msg)) {
        $msg .= "\n" if (!($msg =~ /\n$/));
        prt($msg);
    }
    show_warnings($val);
    close_log($outfile,$load_log);
    exit($val);
}


sub prtw($) {
   my ($tx) = shift;
   $tx =~ s/\n$//;
   prt("$tx\n");
   push(@warnings,$tx);
}

sub get_git_parent($) {
    my $path = shift;
    $path = path_d2u($path);
    my @arr = split("/",$path);
    my ($p,$n);
    $p = '';
    foreach $n (@arr) {
        if ($n eq '.git') {
            return $p;
        }
        $p = $n;
    }
    return "";
}


sub process_in_file($$$) {
    my ($inf,$tim,$siz) = @_;
    if (! open INF, "<$inf") {
        #pgm_exit(1,"ERROR: Unable to open file [$inf]\n"); 
        prt("ERROR: Unable to open file [$inf]\n"); 
        return;
    }
    my @lines = <INF>;
    close INF;

    my $lncnt = scalar @lines;
    #prt("Processing $lncnt lines, from [$inf]...\n");
    my ($line,$inc,$lnn,$sb,$dtt,$tm,$len);
    my $p = get_git_parent($inf);
    $dtt = '';
    if ($sb = stat($inf)) {
        $tm = $sb->mtime;
        $dtt = get_YYYYMMDD($tm);
    }
    $lnn = 0;
    my $inremote = 0;
    # [remote "origin"]
    foreach $line (@lines) {
        chomp $line;
        $lnn++;
        if ($line =~ /^\[(.+)\]/) {
            $inc = $1;
            if (($inc =~ /remote/)&&($inc =~ /origin/)) {
                $inremote = 1;
            } else {
                $inremote = 0;
            }
        } elsif ($line =~ /\s*url\s*=\s*(.+)$/) {
            $inc = $1;
            ##prt("$p: $inc $dtt\n");
            if ($inremote) {
                $repos_found{$inc} = 1;
                push(@gitrepos,[$p,$inc,$tim,$siz]);
                $len = length($p);
                $max_path = $len if ($len > $max_path);
                $len = length($inc);
                $max_repo = $len if ($len > $max_repo);
            }
        }
    }
}

sub mycmp_decend_n2 {
   return 1 if (${$a}[2] < ${$b}[2]);
   return -1 if (${$a}[2] > ${$b}[2]);
   return 0;
}

sub mycmp_ascend_n2 {
   return -1 if (${$a}[2] < ${$b}[2]);
   return  1 if (${$a}[2] > ${$b}[2]);
   return  0;
}

sub process_git_dir($$);

sub process_git_dir($$) {
    my ($dir,$lev) = @_;
	if ( !opendir( DIR, $dir ) ) {
        prtw("WARNING: Unable to open dir $dir!\n");
        return;
    }
	my @files = readdir(DIR);
	closedir DIR;
    my ($itm,$ff,$sb,$sz,$cfg,$tm);
    ut_fix_directory(\$dir);
    my @dirs = ();
    my $total_size = 0;
    my $last_time = 0;
    $cfg = $dir.'config';
    $total_dirs++;
	foreach $itm (@files) {
        next if ($itm eq '.');
        next if ($itm eq '..');
        $ff = $dir.$itm;
        if (-f $ff) {
            if ($sb = stat($ff)) {
                $sz = $sb->size;
                $tm = $sb->mtime;
                $total_size += $sz;
                $last_time = $tm if ($tm > $last_time);
            }
            $total_files++;
        } elsif (-d $ff) {
            push(@dirs,$ff);
        }
    }
    foreach $dir (@dirs) {
        ($tm,$sz) = process_git_dir($dir,$lev+1);
        $total_size += $sz;
        $last_time = $tm if ($tm > $last_time);
    }
    if (($lev == 0)&&(-f $cfg)) {
        process_in_file($cfg,$last_time,$total_size);
    }
    return ($last_time,$total_size);
}


sub process_in_dir($) {
    my ($dir) = @_;
	if ( !opendir( DIR, $dir ) ) {
        prtw("WARNING: Unable to open dir $dir!\n");
        return;
    }
	my @files = readdir(DIR);
	closedir DIR;
    my ($itm,$ff,$sb,$sz,$cfg);
    ut_fix_directory(\$dir);
    my @dirs = ();
    $total_dirs++;
	foreach $itm (@files) {
        next if ($itm eq '.');
        next if ($itm eq '..');
        $ff = $dir.$itm;
        if (-f $ff) {
            if ($sb = stat($ff)) {
                $sz = $sb->size;
            }
            $total_files++;
        } elsif (-d $ff) {
            ##$cfg = $ff.$PATH_SEP.".git".$PATH_SEP."config";
            $cfg = $ff.$PATH_SEP.".git";
            if (-d $cfg) {
                process_git_dir($cfg,0);
            }
        }
    }
}

# 2016/02/22 git@github.com:fgx/fgx-globe.git             fgx-globe                162197104
sub show_git_repos($) {
    my $dir = shift;
    my @gitreposs = sort mycmp_ascend_n2 @gitrepos;
    my $cnt = scalar @gitreposs;
    my $cnt2 = scalar keys %repos_found;
    my $msg = "Found $cnt git repos, $cnt2 diff, in subs of '$dir'. Did $total_dirs dirs, $total_files files.";
    prt("$msg\n");
    my ($p,$r,$t,$s,$dtt,$ra,$siz,$tmp,$space,$len);
    $dtt = get_YYYYMMDD(time());
    $tmp = 'Date';
    $tmp .= ' ' while (length($tmp) < length($dtt));
    my $hdr = $tmp.' ';
    $r = 'Repository';
    $r .= ' ' while (length($r) < $max_repo);
    $hdr .= "$r ";
    $p = 'Directory';
    $p .= ' ' while (length($p) < $max_path);
    $hdr .= "$p ";
    $len = length($hdr);
    $space = ' ' x $len;
    $siz = sprintf("%12u",1234);
    $tmp = 'Size';
    $tmp = ' '.$tmp while (length($tmp) < length($siz));
    $hdr .= $tmp;
    prt("$hdr\n");
    my $repo_total = 0;
    my $repeat_total = 0;
    my %done = ();
    foreach $ra (@gitreposs) {
        $p = ${$ra}[0];
        $r = ${$ra}[1];
        $t = ${$ra}[2];
        $s = ${$ra}[3];
        $tmp = '';
        if (defined $done{$r}) {
            $tmp = 'R';
            $repeat_total += $s;
        }
        $done{$r} = 1;
        $dtt = get_YYYYMMDD($t);
        $repo_total += $s;
        # display
        $p .= ' ' while (length($p) < $max_path);
        $r .= ' ' while (length($r) < $max_repo);
        $siz = sprintf("%12u",$s);
        prt("$dtt $r $p $siz $tmp\n");
    }
    $siz = sprintf("%12u",$repo_total);
    $tmp = '';
    if ($repeat_total) {
        $tmp = sprintf("R=%u",$repeat_total);
    }
    prt($space.$siz." $tmp\n");
    prt("$msg\n") if ($cnt > 10);
}

#########################################
### MAIN ###
parse_args(@ARGV);
process_in_dir($in_dir);
show_git_repos($in_dir);
pgm_exit(0,"");
########################################

sub need_arg {
    my ($arg,@av) = @_;
    pgm_exit(1,"ERROR: [$arg] must have a following argument!\n") if (!@av);
}

sub parse_args {
    my (@av) = @_;
    my ($arg,$sarg);
    my $verb = VERB2();
    while (@av) {
        $arg = $av[0];
        if ($arg =~ /^-/) {
            $sarg = substr($arg,1);
            $sarg = substr($sarg,1) while ($sarg =~ /^-/);
            if (($sarg =~ /^h/i)||($sarg eq '?')) {
                give_help();
                pgm_exit(0,"Help exit(0)");
            } elsif ($sarg =~ /^v/) {
                if ($sarg =~ /^v.*(\d+)$/) {
                    $verbosity = $1;
                } else {
                    while ($sarg =~ /^v/) {
                        $verbosity++;
                        $sarg = substr($sarg,1);
                    }
                }
                $verb = VERB2();
                prt("Verbosity = $verbosity\n") if ($verb);
            } elsif ($sarg =~ /^l/) {
                if ($sarg =~ /^ll/) {
                    $load_log = 2;
                } else {
                    $load_log = 1;
                }
                prt("Set to load log at end. ($load_log)\n") if ($verb);
            } elsif ($sarg =~ /^o/) {
                need_arg(@av);
                shift @av;
                $sarg = $av[0];
                $out_file = $sarg;
                prt("Set out file to [$out_file].\n") if ($verb);
            } else {
                pgm_exit(1,"ERROR: Invalid argument [$arg]! Try -?\n");
            }
        } else {
            $in_dir = $arg;
            prt("Set input to [$in_dir]\n") if ($verb);
        }
        shift @av;
    }

    if ($debug_on) {
        prtw("WARNING: DEBUG is ON!\n");
        if (length($in_dir) ==  0) {
            $in_dir = $def_file;
            prt("Set DEFAULT input to [$in_dir]\n");
        }
    }
    if (length($in_dir) ==  0) {
        pgm_exit(1,"ERROR: No input files found in command!\n");
    }
    if (! -d $in_dir) {
        pgm_exit(1,"ERROR: Unable to find in directory [$in_dir]! Check name, location...\n");
    }
}

sub give_help {
    prt("$pgmname: version $VERS\n");
    prt("Usage: $pgmname [options] in-file\n");
    prt("Options:\n");
    prt(" --help  (-h or -?) = This help, and exit 0.\n");
    prt(" --verb[n]     (-v) = Bump [or set] verbosity. def=$verbosity\n");
    prt(" --load        (-l) = Load LOG at end. ($outfile)\n");
    prt(" --out <file>  (-o) = Write output to this file.\n");
}

# eof - template.pl